Android项目Jenkins流水线构建并自动上传蒲公英发钉钉安装二维码

一 背景

之前测试同学或产品同学需要测试或验收android端时，都需要找android同学打包，修复了问题后还是要找android同学打包上传蒲公英之后，才能测。
而有了jenkins流水线构建之后，Android开发同学就可以解脱了，测试同学和产品同学也不用等着Android同学打包上传了，Android开发同学修复问题之后，测试同学和产品同学都可以直接到Jenkins触发构建，下载二维码就会自动发到钉钉群里，直接扫码下载即可测试，方便快捷。

二 先看效果

Jenkins构建流水线

钉钉消息

三 建流水线前准备

1 在Jenkins机器上下载android-sdk

# 下载地址 http://tools.android-studio.org/index.php/sdk/
wget http://dl.google.com/android/android-sdk_r24.4.1-linux.tgz
tar -zvxf android-sdk_r24.4.1-linux.tgz
mv android-sdk-linux /usr/local/

2 配置环境变量

vim /etc/profile
ANDROID_HOME=/usr/local/android-sdk-linux
PATH=$ANDROID_HOME/tools:$PATH
export ANDROID_HOME
export PATH


# 生效环境变量
resource /etc/profile

3 更新各个版本的sdk

android list sdk --all
# 按序列号update
android update sdk -u --all --filter 1,2,19,20,21,22,23,24,25,27,29,35,36,46,47,48,49,50,51,52,53,54,55,56,57,202
# 3至18也需要安装
android update sdk -u --all --filter 3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18

4 Jenkins配置

• 配置android-sdk环境变量

  系统管理 -> 系统配置 找到 全局属性环境变量新增以下环境变量

  变量名：ANDROID_HOME

  变量值：/usr/local/android-sdk-linux

四 流水线脚本

流水线脚本，直接在jenkins上创建流水线，写入如下脚本，提示确实插件请自行安装。

pipeline {
    agent any
    
    environment {
        // 构建用户ID
        BUILD_USER_ID = ''
        // 钉钉机器人的token
        DINGDING_TOKEN = 'xxxxxxxxxxxxxxxxxxxxxxxxxxxx'
        // 蒲公英的uKey和apiKey
        pgyer_u_key = 'xxxxxxx'
        pgyer_api_key = 'xxxxxxxx'
        // GITLAB的地址
        gitlab_url = 'git@gitlab.xxxxx:xxxx/xxxxxx.git'
    }
    
    parameters {
        choice name: 'PACKAGE_TYPE', choices: ['Release', 'Debug'], description: '打包类型 Release为生产包(访问正式环境接口) Debug 为开发包(访问开发环境接口)'
        choice name: 'CHANNEL', choices: ['all', 'huawei', 'xiaomi', 'oppo', 'vivo', 'meizu'], description: '选择打包渠道 all为全渠道'
        choice name: 'BRANCH', choices: ['master', 'dev'], description: '选择分支（正常发布Release版本要选择master分支）'
        string name: 'SUB_DIR', defaultValue: 'zinverService', description: '项目子目录', trim: true
    }
    
    stages {
        stage('Preparation') {
            steps {
                wrap([$class: 'BuildUser']) {
                     script {
                         BUILD_USER_ID = "${env.BUILD_USER_ID}"
                     }
                }
                script {
                    git branch: params.BRANCH, credentialsId: '1d431fd2-c3b4-4961-ad99-242cca82a5ad', url: env.gitlab_url
                    def gradleHome = tool "Gradle 5.6.4"
                    env.PATH = "${gradleHome}/bin:${PATH}"
                    currentBuild.displayName = "#${BUILD_NUMBER} by ${BUILD_USER_ID}"
                }
            }
        }
        stage('Compile & Package') {
            steps {
                script {
                    dir("${SUB_DIR}") {
                        sh 'gradle -v'
                        println 'channel is ${CHANNEL}'
                        if ("all".equals(params.CHANNEL)) {
                            sh 'gradle clean assemble${PACKAGE_TYPE}Channels'
                        } else {
                            sh 'gradle clean assemble${PACKAGE_TYPE}Channels -PchannelList=${CHANNEL}'
                        }
                    }
                }
            }
        }
        stage('Upload') {
            steps {
                script {
                    dir("${SUB_DIR}") {
                        def uploadResult
                        if ('Release'.equals(params.PACKAGE_TYPE)) {
                            println 'upload release package'
                            uploadResult = sh(script: "curl -F 'file=@app/build/outputs/apk/release/app-release.apk' -F 'uKey=${env.pgyer_u_key}' -F '_api_key=${env.pgyer_api_key}' https://upload.pgyer.com/apiv1/app/upload", returnStdout: true)
                        } else {
                            println 'upload debug package'
                            uploadResult = sh(script: "curl -F 'file=@app/build/outputs/apk/debug/app-debug.apk' -F 'uKey=${env.pgyer_u_key}' -F '_api_key=${env.pgyer_api_key}' https://upload.pgyer.com/apiv1/app/upload", returnStdout: true)
                        }
                        println "upload result is \n ${uploadResult}"
                        def resultcode = sh(script: "echo ${uploadResult} | grep -Po 'code[\" :]+\\K[^\", \\}]+' | tr -d '\\n\\r'", returnStdout: true)
                        println "result code is ${resultcode}"
                        if ('0'.equals(resultcode)) {
                            println 'upload success'
                            env.qrCodeUrl = sh(script: "echo ${uploadResult} | grep -Po 'appQRCodeURL[\" :]+\\K[^\", \\}]+' | tr -d '\\n\\r'", returnStdout: true)
                            // currentBuild.setDescription('<img src="' + qrCodeUrl + '" />')
                            // currentBuild.description = '<img src="' + qrCodeUrl + '" />'
                        } else {
                            def message = sh(script: "echo ${uploadResult} | grep -Po 'message[\" :]+\\K[^\"\\}]+' | tr -d '\\n\\r'", returnStdout: true)
                            env.failMsg = "upload fail, fail message is ${message}"
                            println "${failMsg}"
                        }
                    }
                }
            }
        }
        stage('SendDingMsg') {
            steps {
                script {
                    def buildTitle = env.failMsg != null && env.failMsg != '' ? '构建失败' : '构建成功'
                    def content = "项目【${env.JOB_NAME}】${buildTitle} \\n\\n " +
                            ">构建用户: ${BUILD_USER_ID} \\n\\n " +
                            ">构建版本: #${env.BUILD_NUMBER} \\n\\n " +
                            ">打包类型: ${PACKAGE_TYPE} \\n\\n " +
                            ">打包渠道: ${CHANNEL} \\n\\n " +
                            ">打包分支: ${BRANCH} \\n\\n " +
                            ">构建详情: [点击查看](${env.BUILD_URL}) \\n\\n " +
                            (env.failMsg != null && env.failMsg != '' ? ">失败信息: ${env.failMsg} \\n\\n" : '') + 
                            ">构建APP:  \\n\\n ![image-20210517211443871](${env.qrCodeUrl})"
                    def message =
                            """
                {
                    "msgtype": "markdown",
                    "markdown": {
                        "title": "${buildTitle}(${env.JOB_NAME})",
                        "text": "${content}"
                    }
                }
                """
                    sh("curl -s -XPOST -H 'Content-Type: application/json' https://oapi.dingtalk.com/robot/send?access_token=${env.DINGDING_TOKEN} -d '${message}'")
                }
            }
        }
    }
}

第一次触发构建会失败，因为会去初始化参数化构建的那些参数，第二次触发构建就会看到有以下可选参数：